Added two new functions: estap:not_ok() and estap:error().
[erlang-estap.git] / src / estap.erl
1 %%%---------------------------------------------------------------------------
2 %%% @doc
3 %%%   Functions to use in test cases.
4 %%%
5 %%%   Test passes if it returns or throws (`throw()'): `ok', `{ok, Value}', or
6 %%%   `true'.
7 %%%
8 %%%   Test fails if it returns or throws `error', `{error, Reason}', `false',
9 %%%   or calls `exit(...)' or `erlang:error(...)' (or simply dies).
10 %%%
11 %%%   Any other returned value is also considered a failure, but a dubious
12 %%%   one. Stick to saying explicitly that the test failed.
13 %%%
14 %%%   All test functions return the value they were passed (an exception to
15 %%%   this rule are {@link pass/1} and {@link fail/1} functions, for obvious
16 %%%   reason). This allows test to be added around preparation function call
17 %%%   for more complex test cases.
18 %%% @end
19 %%%---------------------------------------------------------------------------
20
21 -module(estap).
22
23 %% public interface
24 -export([ok/2, not_ok/2, error/2]).
25 -export([pass/1, fail/1]).
26 -export([is/3, isnt/3, eq/3, ne/3, cmp/4]).
27 -export([like/3, unlike/3, matches/3]).
28 -export([bail_out/1, no_plan/0, plan/1, all_ok/0]).
29 -export([diag/1, diag/2, info/1, info/2, explain/1]).
30 -export([test_dir/0, test_dir/1]).
31
32 -export_type([value/0, cmp/0, regexp/0, match_fun/0]).
33
34 %%%---------------------------------------------------------------------------
35 %%% types {{{
36
37 -type value() :: term().
38
39 -type cmp() :: '<' | '>' | '=<' | '>=' | '/=' | '=/=' | '==' | '=:='.
40
41 -type regexp() :: iolist().
42
43 -type match_fun() :: fun((value()) -> any()).
44
45 -type message() :: iolist().
46
47 -type description() :: iolist().
48
49 -type info() :: atom() | iolist() |
50                 {FieldName :: atom() | iolist(), Value :: atom() | iolist()}.
51
52 %%% }}}
53 %%%---------------------------------------------------------------------------
54 %%% public interface
55 %%%---------------------------------------------------------------------------
56
57 %% @doc Check if `Value' is any of the recognized truth values.
58 %%
59 %% @see not_ok/2
60 %% @see error/2
61
62 -spec ok(value(), description()) ->
63   Value :: value().
64
65 ok(Value, Description) ->
66   report(estap_test:success_or_failure(Value), Description),
67   Value.
68
69 %% @doc Check if `Value' is none of the recognized truth values.
70 %%
71 %%   Dubious `Value' is also a success here.
72 %%
73 %% @see ok/2
74 %% @see error/2
75
76 -spec not_ok(value(), description()) ->
77   Value :: value().
78
79 not_ok(Value, Description) ->
80   case estap_test:success_or_failure(Value) of
81     {success, _} -> report({failure, Value}, Description);
82     {failure, _} -> report({success, Value}, Description);
83     {dubious, _} -> report({success, Value}, Description)
84   end,
85   Value.
86
87 %% @doc Check if `Value' is any of the recognized falsity values.
88 %%
89 %% @see ok/2
90 %% @see not_ok/2
91
92 -spec error(value(), description()) ->
93   Value :: value().
94
95 error(Value, Description) ->
96   case estap_test:success_or_failure(Value) of
97     {success, _} -> report({failure, Value}, Description);
98     {failure, _} -> report({success, Value}, Description);
99     {dubious, _} -> report({dubious, Value}, Description)
100   end,
101   Value.
102
103 %% @doc Mark the test as a success unconditionally.
104
105 -spec pass(description()) ->
106   true.
107
108 pass(Description) ->
109   report({success, explicit}, Description),
110   true.
111
112 %% @doc Mark the test as a failure unconditionally.
113
114 -spec fail(description()) ->
115   false.
116
117 fail(Description) ->
118   report({failure, explicit}, Description),
119   false.
120
121 %% @doc Check if `Value' is the same as `Expected'.
122
123 -spec is(value(), value(), description()) ->
124   Value :: value().
125
126 is(Value, Expected, Description) ->
127   case Value of
128     Expected -> report({success, Value}, Description);
129     _        -> report({failure, Value}, Description)
130   end,
131   Value.
132
133 %% @doc Check if `Value' is different than `Expected'.
134
135 -spec isnt(value(), value(), description()) ->
136   Value :: value().
137
138 isnt(Value, Expected, Description) ->
139   case Value of
140     Expected -> report({failure, Value}, Description);
141     _        -> report({success, Value}, Description)
142   end,
143   Value.
144
145 %% @doc Check if `Value' is equal (`==') to `Expected'.
146
147 -spec eq(value(), value(), description()) ->
148   Value :: value().
149
150 eq(Value, Expected, Description) ->
151   cmp(Value, '==', Expected, Description).
152
153 %% @doc Check if `Value' is not equal (`/=') to `Expected'.
154
155 -spec ne(value(), value(), description()) ->
156   Value :: value().
157
158 ne(Value, Expected, Description) ->
159   cmp(Value, '/=', Expected, Description).
160
161 %% @doc Compare `Value' and `Expected' using comparison operator.
162
163 -spec cmp(value(), cmp(), value(), description()) ->
164   Value :: value().
165
166 cmp(Value, Cmp, Expected, Description) ->
167   CmpResult = case Cmp of
168     '<'   -> Value <   Expected;
169     '>'   -> Value >   Expected;
170     '=<'  -> Value =<  Expected;
171     '>='  -> Value >=  Expected;
172     '/='  -> Value /=  Expected;
173     '=/=' -> Value =/= Expected;
174     '=='  -> Value ==  Expected;
175     '=:=' -> Value =:= Expected
176   end,
177   % FIXME: better reporting for failures
178   case CmpResult of
179     true  -> report({success, Value}, Description);
180     false -> report({failure, Value}, Description)
181   end,
182   Value.
183
184 %% @doc Check if `Value' matches a regexp.
185
186 -spec like(value(), regexp(), description()) ->
187   Value :: value().
188
189 like(Value, Expected, Description) ->
190   % XXX: regular expression may be invalid, so prepare estap_server before
191   % running the regexp
192   TestRun = get_test_run(),
193   estap_server:running(TestRun, Description),
194   case re:run(Value, Expected) of
195     {match, _Capture} -> estap_server:report_result(TestRun, {success, Value});
196     nomatch           -> estap_server:report_result(TestRun, {failure, Value})
197   end,
198   Value.
199
200 %% @doc Check if `Value' not matches a regexp.
201
202 -spec unlike(value(), regexp(), description()) ->
203   Value :: value().
204
205 unlike(Value, Expected, Description) ->
206   % XXX: regular expression may be invalid, so prepare estap_server before
207   % running the regexp
208   TestRun = get_test_run(),
209   estap_server:running(TestRun, Description),
210   case re:run(Value, Expected) of
211     {match, _Capture} -> estap_server:report_result(TestRun, {failure, Value});
212     nomatch           -> estap_server:report_result(TestRun, {success, Value})
213   end,
214   Value.
215
216 %% @doc Check if `Value' pattern-matches.
217 %%   Pattern is specified as a fun that has clauses defined only for what
218 %%   should match, i.e., calling the fun should fail with `function_clause'
219 %%   error. Return value of the fun is ignored.
220
221 -spec matches(value(), match_fun(), description()) ->
222   Value :: value().
223
224 matches(Value, MatchSpec, Description) ->
225   TestRun = get_test_run(),
226   estap_server:running(TestRun, Description),
227   try
228     MatchSpec(Value),
229     estap_server:report_result(TestRun, {success, Value})
230   catch
231     error:function_clause ->
232       estap_server:report_result(TestRun, {failure, Value})
233   end,
234   Value.
235
236 %%%---------------------------------------------------------------------------
237
238 %% @doc Stop testing whatsoever because something terrible happened.
239 %%
240 %%   Note that bailing out is a very severe operation. It aborts all test
241 %%   cases, including the ones in other scripts that were not executed yet.
242 %%   It should be only used when an error that occurred renders whole test
243 %%   suite unusable before it's fixed.
244
245 -spec bail_out(message()) ->
246   no_return().
247
248 bail_out(Message) ->
249   TestRun = get_test_run_or_parent(),
250   estap_server:bail_out(TestRun, Message),
251   exit('BAIL_OUT').
252
253 %% @doc Set the "no plan" plan for sub-tests.
254 %%   Calling this function may be safely skipped.
255 %%
256 %% @see all_ok/0
257
258 -spec no_plan() ->
259   ok.
260
261 no_plan() ->
262   _TestRun = get_test_run(),
263   ok.
264
265 %% @doc Set expected number of sub-tests.
266
267 -spec plan(pos_integer()) ->
268   ok.
269
270 plan(TestCount) when is_integer(TestCount) ->
271   TestRun = estap_server:subplan(TestCount, 1),
272   set_test_run(TestRun),
273   ok.
274
275 %% @doc Check if all the current sub-tests were OK.
276 %%   Function intended to be called at the end of a sequence of sub-tests, to
277 %%   indicate that the test sequence passed or failed.
278
279 -spec all_ok() ->
280   true | false.
281
282 all_ok() ->
283   TestRun = get_test_run(),
284   {Planned, Total, Failed, _TODO} = estap_server:get_status(TestRun),
285   estap_server:done(TestRun), % this ends estap_server, so it goes last
286   (Failed == 0) and ((Planned == undefined) or (Planned == Total)).
287
288 %%%---------------------------------------------------------------------------
289
290 %% @doc Get a directory containing this test script.
291 %%
292 %%   <b>NOTE</b>: This function doesn't work in processes spawned from test
293 %%   function. You need to get the directory in parent process and pass it as
294 %%   an argument.
295
296 test_dir() ->
297   case get(test_dir) of
298     undefined -> erlang:error({undefined, test_dir});
299     Directory -> Directory
300   end.
301
302 %% @doc Get a subdirectory of the directory containing this test script.
303 %%
304 %%   <b>NOTE</b>: This function doesn't work in processes spawned from test
305 %%   function. You need to get the directory in parent process and pass it as
306 %%   an argument.
307
308 test_dir(Subdir) ->
309   filename:join(test_dir(), Subdir).
310
311 %%%---------------------------------------------------------------------------
312
313 %% @doc Print a diagnostic message.
314 %%   Typically, diagnostic message is a warning, but may be notice important
315 %%   enough to print it along with test progress by TAP consumer.
316 %%
317 %%   Before first call to {@link plan/1}, {@link no_plan/0} or test functions
318 %%   ({@link ok/2}, {@link is/3} etc.) message is printed at the level of
319 %%   parent test. After any of those, it's printed at sub-test level.
320 %%
321 %%   Normally diagnostic output goes to <i>STDERR</i>, but under TODO tests it
322 %%   goes to <i>STDOUT</i>.
323 %%
324 %% @TODO Make the diagnostic output go to <i>STDOUT</i> under TODO
325
326 -spec diag(message()) ->
327   ok.
328
329 diag(Message) ->
330   TestRun = get_test_run_or_parent(),
331   estap_server:warning(TestRun, Message).
332
333 %% @doc Print a warning with some context.
334 %%   Typically, diagnostic message is a warning, but may be notice important
335 %%   enough to print it along with test progress by TAP consumer.
336 %%
337 %%   Before first call to {@link plan/1}, {@link no_plan/0} or test functions
338 %%   ({@link ok/2}, {@link is/3} etc.) message is printed at the level of
339 %%   parent test. After any of those, it's printed at sub-test level.
340 %%
341 %%   Normally diagnostic output goes to <i>STDERR</i>, but under TODO tests it
342 %%   goes to <i>STDOUT</i>.
343 %%
344 %% @TODO Make the diagnostic output go to <i>STDOUT</i> under TODO
345
346 -spec diag(message(), [info()]) ->
347   ok.
348
349 diag(Message, Info) ->
350   TestRun = get_test_run_or_parent(),
351   InfoLines = [["  ", format_info(I), "\n"] || I <- Info],
352   estap_server:warning(TestRun, [Message, "\n", InfoLines]).
353
354 %% @doc Print a message.
355 %%
356 %%   Before first call to {@link plan/1}, {@link no_plan/0} or test functions
357 %%   ({@link ok/2}, {@link is/3} etc.) message is printed at the level of
358 %%   parent test. After any of those, it's printed at sub-test level.
359
360 -spec info(message()) ->
361   ok.
362
363 info(Message) ->
364   TestRun = get_test_run_or_parent(),
365   estap_server:info(TestRun, Message).
366
367 %% @doc Print a message with some context.
368 %%
369 %%   Before first call to {@link plan/1}, {@link no_plan/0} or test functions
370 %%   ({@link ok/2}, {@link is/3} etc.) message is printed at the level of
371 %%   parent test. After any of those, it's printed at sub-test level.
372
373 -spec info(message(), [info()]) ->
374   ok.
375
376 info(Message, Info) ->
377   TestRun = get_test_run_or_parent(),
378   InfoLines = [["  ", format_info(I), "\n"] || I <- Info],
379   estap_server:info(TestRun, [Message, "\n", InfoLines]).
380
381 %% @doc Format a single info entry for printing it on screen.
382
383 -spec format_info(info()) ->
384   binary().
385
386 format_info(Info) when is_list(Info); is_binary(Info) ->
387   iolist_to_binary(Info);
388 format_info(Info) when is_atom(Info) ->
389   atom_to_binary(Info, unicode);
390 format_info({K, V} = _Info) ->
391   <<(format_info(K))/binary, ": ", (format_info(V))/binary>>.
392
393 %% @doc Format term so it can be printed to screen.
394 %%   Convenience wrapper for {@link io_lib:format/2}.
395 %%
396 %% @see info/2
397 %% @see diag/2
398
399 -spec explain(term()) ->
400   iolist().
401
402 explain(Term) ->
403   % no term should weigh 1MB
404   io_lib:print(Term, 1, 1024 * 1024, -1).
405
406 %%%---------------------------------------------------------------------------
407
408 %% @doc Set previously started {@link estap_server}.
409
410 set_test_run(TestRun) ->
411   put(estap_server, TestRun).
412
413 %% @doc Get associated {@link estap_server}, starting it if necessary.
414
415 get_test_run() ->
416   case get(estap_server) of
417     undefined ->
418       TestRun = estap_server:subplan(no_plan, 1),
419       put(estap_server, TestRun),
420       TestRun;
421     TestRun when is_pid(TestRun) ->
422       TestRun
423   end.
424
425 %% @doc Get associated {@link estap_server} or parent one if none is started
426 %%   yet. Necessary for top-level {@link info/1} and {@link diag/1} to work.
427
428 get_test_run_or_parent() ->
429   case get(estap_server) of
430     undefined ->
431       % XXX: this must be set in `estap_test:run()'
432       get(estap_server_parent);
433     TestRun when is_pid(TestRun) ->
434       TestRun
435   end.
436
437 %% @doc Send a test report to {@link estap_server}.
438
439 -spec report({success | failure | dubious, Value :: value()}, description()) ->
440   ok.
441
442 report({T,_V} = Report, Description)
443 when T == success; T == failure; T == dubious ->
444   TestRun = get_test_run(),
445   estap_server:running(TestRun, Description),
446   estap_server:report_result(TestRun, Report),
447   ok.
448
449 %%%---------------------------------------------------------------------------
450 %%% vim:ft=erlang:foldmethod=marker